魔兽世界宏教程,目标是,让所有玩家都能自己写宏!

文 WOW吧/Rekuangre

1.什么是宏

所谓宏,就是一些命令组织在一起,作为一个单独命令完成一个特定任务,在魔兽世界中,宏能使我们的游戏更加的方便!仅此而已.

学会做宏,能让自己的游戏旅程更加的便捷,更加的愉快

2.怎么做宏

这是困扰很多小白的问题.
楼主用图片的方式更直观的表现出来

ab815d43fbf2b211c3bbfc95ca8065380ed78e89
如图所示
ESC ,选择宏命令设置 打开的列表中选择新建,开始建宏
1da7a6d3fd1f413437817ca5251f95cad3c85ef4

37ed9aeef01f3a29af5dac159925bc315e607c89
宏可以取名和设置图标,如果设置为?图标的话就是自动选择宏技能的图标.也可以自己设置一个喜欢的图标啦.蛤铪...

*通用宏和专用宏的区别
通用宏指的是在你的账号下所有角色都能使用这个宏,而专用宏就是只有当前这个角色才能使用.

3.做宏的规则

A.不能逾越角色能力以外的技能

B.不能做带有BUG性质的宏

C.共CD的技能不能通过宏来实现一键使用

D.宏不能超过255个字符,每个英文字母是一个字符,汉字是两个字符.如果包含汉字且超过了255个字符但没超过255个字,在保存时是不会出现问题的,但是下线以后会丢失宏内容

E.也是最重要的一点.除去技能名之外所有的标点符号和字母都是英文半角的!

F.技能名之间一般用";"间隔,而castsequence中队列里的技能名则用","间隔.需要同时满足的条件由中括号"[]"包裹,","间隔

额外提醒(楼下的红字加粗部分也请额外注意)

*关于判断宏: 暴雪现在已经禁止在宏命令中使用判断语句,所以请不要再求20%血一下斩杀/有5层buff用弹幕 这一类的宏了...

4.常用的宏命令

/cast
释放一个或多个技能,可以加入一些条件判断,是最常用的命令

/castsequence
依次释放释放数个技能,同样可以加入一些条件判断,常见于所谓的"无脑宏"

/cancelform
取消变形

/cancelaura
取消状态或增益

/startattack
开始攻击,一般写不写差别不大,释放技能会自动开始攻击的

/stopattack
停止攻击,与startattack相反,用于防止破除控制等功能,也不大会用到

/target
目标

/targetenemy
切换目标,抓贼宏经常用到

/equip
装备武器

/mount
召唤坐骑

/dismount
解散坐骑

语言表情命令/s /y /p /ra /bg /e
/S 在当前频道用白字说

/Y 在当前频道用红字喊话

/P 在小队频道说

/RA 在团队频道说

/E 表情命令,例如 /E觉得楼主是个大帅哥 聊天频道将会显示
cdb04536acaf2eddc3da33328d1001e93801937f
#showtooltip
显示技能描述,可以指定技能名,也可以什么都不写
如图
0a8c3dfa828ba61e3306b3f44134970a324e59be
没有指定技能名字,鼠标移上去的时候显示的就是宏里面的技能-消失

但是指定了显示为潜行,鼠标移上去的时候显示的是潜行,使用的时候依然是使用消失
如图
0f36825494eef01f45f4631ee0fe9925be317d46

%t
当前目标的名字
多用在喊话宏中
如选中一个目标 然后
/E 觉得%t可以给他点金币
ae7738d3d539b6007eb3756ce950352ac75cb721

/focus
指定某个目标为焦点目标
如 /focus targettarget 指定目标的目标为焦点

/clearfocus
清除焦点目标

/stopmacro
停止宏命令

/script
控制命令

/run
运行脚本

/in x
多用在语句前 意思是X秒后执行这段语句
例如

/CAST 深度冻结
/IN 4 /Y 你已经死了

5.常用的判断命令

所谓判断命令,跟宏命令不一样,一般都是穿插在宏的语句中,起到判断条件的作用

例如
/cast [help] 冰枪术
/cast [harm] 奥术智慧
这个宏的意思就是目标友善给他拍智力 而目标敌对则使用BIU

常用的判断命令有

help
目标为友方

harm
目标为敌方

exists
目标存在

dead
目标死亡

nodead
目标存活

combat
战斗状态

nocombat
非战斗状态

stealth
潜行中

nostealth
非潜行中

mod:alt
按下功能键alt时,同理可以改成shift和ctrl

swimming
游泳中

noswimming
非游泳中

flyable
可飞行时

noflyable
不可飞行时

indoors
在室内时

outdoors
在室外时

`*target条件语句的用法

很多人可以在焦点打断宏里面找到这么一句 [target=focus] 这句话的意思就是释放技能的目标为焦点,同理的,可以改成
target=player/focus/targettarget/mouseover/pet 分别代表目标为玩家/焦点/目标的目标/鼠标指向的目标/宠物`

*reset 重置命令
reset=X/target/combat/shift/alt/ctrl
这个语句不同于上面的命令.用于/castsequence中,(不需要加中括号"[ ]")这句话的意思是设定重置条件,可以是X秒后/切换目标时/进入战斗时/按住shift时/按住alt/按住ctrl时
如/castsequence reset=alt/30 深度冻结,冰枪术,冰枪术,火焰冲击 这句话的意思就是每次按下这个宏时依次释放深结,biu,biu,火冲.30秒后或者按住ALT时重置这个顺序

*感叹号的妙用
在/CAST 技能名 这个命令之前加入一个感叹号,能做到在变形/潜行姿态下不取消变形和潜行,也可以做到让战士在战斗姿态下切战斗姿态...(耍酷)
别的职业不知道还有没有用途

如图
这个宏的意思就是丢了深结三秒后说话
2596090828381f30eb28e872a9014c086f06f075
不管怎么按都是不会取消潜行的(注意! 必须是英文符号的感叹号!)

#showtooltop
/CAST !潜行

6.数字代表的装备

本来楼主是不打算写的...
但是很多人都找楼主要饰品宏手套宏腰带宏什么的.
楼主就一张图直观的展示吧
0cfc4da98226cffcf62eda69b9014a90f703ea1b
每一个数字都代表着你装备栏中的装备 如图
例如要使用第一格饰品
只需要在宏里面输入/CAST 13
就OK了,其他部位同理

而装备命令
/equip 16 武器名称
/equip 17 武器名称
就是换武器宏啦

*饰品和工程手套有几十秒的公CD,这个还请各位自行协调...

7.一些简单宏的实例制作.

楼主在这个版块主要是教大家做一些简单的宏(废话),日常生活中别人找你要的最多的也是这种宏.好的,下面开始.

A.大家喜闻乐见的上马宏(马宏:LZ我CNM!)

e9dfde160924ab1850ff84ec35fae6cd79890bbd

#SHOWTOOLTIP
/cast 奥的灰烬
/Y 上马不喊话,三开战猎萨!

效果就如图所示了
4054a564034f78f02a01fe2879310a55b2191c18
坐骑名字和喊话内容大家随意改啦

当然,我们还可以再稍微改良一下.
6d31da3f8794a4c2c58e83f00ef41bd5af6e39f1
效果如图底部,是不是很屌炸天啊?

B.释放技能喊话宏

这个也属于比较简单的一种类型
70aa47540923dd54df95c3b3d109b3de9e824844

#SHOWTOOLTIP
/cast 闪避
/Y 偶吧**塞!

效果就如图所示了
43a08818367adab4beff7c988bd4b31c8601e47c
不仅可以设置/Y 也可以设置成/S /P /RA 等,参照之前的命令说明.

C.简单的循环技能宏.

例句
#showtooltip
/castsequence X,X,X X为技能名称

例如
#showtooltip
/castsequence reset=25 暗影步,偷袭,致盲

这个宏的意思是
轮流使用暗步,偷袭,致盲这三个技能 25秒后循环重置

值得一提的是因为延迟等原因,reset=X的这个X数字最好改成技能循环中CD最长技能的CD再加一秒.

D.取消buff宏

/cancelaura
这种宏比较中端了,平时基本用不上

例如
#showtooltip
/cancelaura 潜行
d960fcd3572c11dfa4b2d9f8632762d0f503c2c7
其他的buff也适用

8. 一些稍微有点难的宏制作实例

A.多技能绑一宏不同条件释放

玩宏的人求这种宏应该是最频繁的了...

例句是:
#showtooltip
/cast [条件] 技能
/cast [条件] 技能

例如
#showtooltip
/cast [help,stealth,mod:alt] 暗影步
/cast [harm,combat] 致盲
5e64e91190ef76c6c86d9af09d16fdfaad5167e3
这个宏的意思是
在战斗中,目标敌对,使用致盲,非战斗状态潜行下,目标友善,按下ALT使用暗影步

B.焦点宏or判断目标宏

这种宏主要作用就是不丢失当前目标的情况下对焦点使用技能,也可适用于目标的目标宏,鼠标指向宏等.

例如
#showtooltip
/cast [target=focus] 致盲

致盲焦点
如图 不丢失当前目标,焦点被致盲
09424d166d224f4a3b7010c809f790529a22d1bd
接下来是进阶版

#showtooltip
/cast [target=mouseover,mod:shift] 预谋
/cast 致盲

这个宏的作用是按住shift时 对鼠标指向目标使用预谋 对当前目标使用致盲
如图
当前目标已被致盲,旁边的木桩被鼠标指向预谋
9497b7389b504fc2b365d2dee5dde71191ef6d68
090edea20cf431ad98e821e24b36acaf2fdd9868
当然,如果卡了公CD ,是不成立的!

有公CD的技能建议使用下面这个句式

#showtooltip

/cast [target=mouseover,mod:shift] 暗影步
/cast [nomod] 预谋

双重判断
按住SHIFT键对鼠标指向目标使用暗影步
什么都不按就使用预谋

如图
什么都不按 对当前目标使用预谋
d960fcd3572c11dfa066ddf8632762d0f503c2eb
按住shift后 暗影步至鼠标指向目标
b1ecbd19ebc4b7459d2bd5cdcffc1e17888215e3

C.超复杂的判断宏

#showtooltip
/cast [target=target,help] [target=mouseover,harm] [target=focus,help] 暗影步

这个宏的作用很简单,如果满足第一个条件,则对目标1释放,否则如果满足第二格条件,则对目标2释放,否则如果满足第三个,则对目标3释放

如图,目标是当前木桩 焦点是路人咕咕 鼠标在另一个木桩上
496a592c11dfa9ec83c33bcc62d0f703938fc1b1
我们释放了暗步 因为第一格条件要求当前目标友善,不成立,于是跳到第二个条件鼠标指向目标敌对,也不成立,最后一个条件焦点是友善,成立,所以我们飞到了被作为焦点的咕咕背后.
0d445c66d016092415dbcfc0d40735fae4cd34ac

D./focus和/clearfocus

/focus这条命令有3个作用
1.没有焦点目标的时候将目标设置为焦点目标
2.有焦点目标的时候将焦点目标更改成当前目标
3.当前目标为空时清空焦点目标
同时这条命令也是可以加条件判断的,如果不加判断的话非常容易误改了焦点

下面楼主做出一个最常见的焦点宏:
没焦点就设焦点,按住alt强制设焦点,焦点死亡就清除焦点
/focus [mod:alt][@focus,noexists]
/clearfocus [@focus,dead]

E.换武器/换盾宏

很多近战喜欢的宏
利用换武器达到他们不可告人的秘密

以战士的盾反宏为例

 #showtooltip 法术反射
/equipslot 16 乌克的猢狲片刀
/equipslot 17 密封甲壳
/cast 法术反射

6f932634349b033b6fe4900115ce36d3d439bd32
武器名字 技能名字可以自己改
(请无视上图的倒数二三句)
其他职业的换武器宏也可以试一试,是一个道理.
好的...模板宏就整理到这里,接下来是一些...成品宏!

9.一些冷门但是实用的宏

A.小德万能变形宏!

这个宏的说明涉及很多,楼主单独拿出来讲而没有放在判断宏里面讲
这个宏的主要作用是在"变形宏"上再加上各种条件判断,实现多种变形一键完成

常用的条件有

[swimming]水栖形态
水里用水栖

[flyable,nocombat]迅捷飞行形态
飞行需要能飞且不战斗

[outdoors,noflyable,nocombat]大型棕色科多兽
不能飞那就只能坐骑了

[outdoors,noflyable,combat]旅行形态
要是还是战斗的话就旅行

[indoors]猎豹形态
室内就只能猎豹了

然后就是每种姿态对应的命令
stance:1/2/3/4/5/6 form:1/2/3/4/5/6 处在某形态中,对应为
野性:1熊,2水栖,3豹,4旅行,5飞行
平衡:1熊,2水栖,3豹,4旅行,5枭兽,6飞行
恢复:1熊,2水栖,3豹,4旅行,5树,6飞行

最后我们直接把以上的全部加到一起,就得到了最终的宏

#showtooltip
/cast [swimming]水栖形态;[flyable,nocombat]迅捷飞行形态;[outdoors,noflyable,nocombat]大型棕色科多兽;[outdoors,noflyable,combat]旅行形态;[indoors]猎豹形态

事实上还有一个化简的问题
例如说/cast [combat]猎豹形态;[nocombat]旅行形态
后面那个nocombat需要吗?不需要
因为判断从左至右进行,判断到第二个的时候就说明第一个没有通过了,那么combat没有通过必然是nocombat了
但由于实际情况有很多条件并列,导致判断某个条件是否需要就比较复杂,有些人可能会绕不过来
下面给出前面宏的化简结果
showtooltip
/cast [swimming]水栖形态;[flyable,nocombat]迅捷飞行形态;[outdoors,nocombat]大型棕色科多兽;[outdoors]旅行形态;猎豹形态
(当然,之前我们提到过还可以加上"!"来防止连按又变回来,注意"!"放在技能名前面)

最后得到最终的宏

#showtooltip
/cast [flyable,nocombat,nomod]!迅捷飞行形态;[form:4,nomod,outdoors][nomod.nocombat,outdoors][noform,outdoors]!旅行形态;[swimming,nomod]!水栖形态;[form:1,nomod]!巨熊形态;[form:3,nomod]!猎豹形态;[form:5,nomod][nomod,indoors]!生命之树
/cancelform [form:6][mod]

(由于宏太长不得已把stance换成form了,效果一样)

当然 别的职业也可以自由发挥,在不同的情况下使用不同的技能/状态

B.技能释放成功喊话宏

这个宏有很多朋友找楼主要,但是由于暴雪的判断机制所以不能完成,所以用下面的宏代替

/run local t,s=GetSpellCooldown("技能名"),SendChatMessage if t==0 then s("你要说的话") end
/cast 技能名

这个宏的作用是几秒内说一次话,能起到不刷屏的效果

C.狼人坐骑相关

上马变人不变狼,狼形态就变人,人形态上马就只是上马

/cast [nomounted] 狂野奔跑
/stopcasting
/cast [nomounted] 双形态
/cast [nomounted] 坐骑名称
/dismount [mounted]

D.盗贼毁伤斩击宏

能斩击打斩击,没斩击打毁伤
(楼主还是不推荐用这个宏,据说在35%以下血的时候也会打出毁伤)

#showtooltip 毁伤 
/startattack 
/castsequence reset=0 9,毁伤 
/castsequence reset=0 斩击,9

E.盗贼背刺出血宏

正面用出血,背面用背刺

#showtooltip 
/castsequence reset=0 16,出血

/cast 背刺

依旧不推荐使用...因为按得快的话在背面也会打出出血...

F.释放技能几秒后喊话宏

这种宏就主要偏向娱乐了

多是用在救人技能,或者一些读条长的技能里面。

我们参考牧师复活宏为例

#showtooltip
/cast 复活术
/in 1 /y "%t"的遗体告别仪式现在开始
/in 3 /y 一鞠躬
/in 5 /y 二鞠躬
/in 7 /y 三鞠躬
/in 9 /y 哎呀妈呀 诈尸啦 快 快跑啊~

再次说明:/IN 后面的数字代表秒数。这个宏的意思是,释放复活术,1秒后,大喊楼主的遗体告别仪式现在开始,3秒后,一鞠躬.5秒后二鞠躬,最后读完条,大喊哎呀妈呀 诈尸啦 快 快跑啊~

当然,宏里面的技能和说话文字以及秒数可以随便改的。这个没有问题

G.技能释放成功喊话宏改良版

这个宏是楼主在网上看到的
不同于楼上
这个宏可以自己设置几秒喊一次话

/run local t=GetTime()macroT=macroT or 0;if t-macroT>3 then SendChatMessage("施放技能","SAY")macroT=t;end
/cast 技能名

其中。第一行里面的macroT>3这个语句中,3代表的就是秒数。
意思为3秒喊一次话。

**真·技能释放成功喊话宏*

这个是楼主刚刚无意中看到的!
看看有没有壮士去游戏中试一下。

施放技能成功后喊话(带目标版)
/run U="UNIT_SPELLCAST_S"F=F or CreateFrame("frame")R=F.RegisterEvent;R(F,U.."ENT")R(F,U.."UCCEEDED")F:SetScript("OnEvent",function(_,_,a,b,_,c)if a=="player"and b=="变形术"then n=type(c)=="string"and c or SendChatMessage(n.."已被我变羊")end end)
/cast 变形术

施放技能成功后喊话(无目标版)
/run F=F or CreateFrame("frame")F:RegisterEvent("UNIT_SPELLCAST_SUCCEEDED")F:SetScript("OnEvent",function()if arg1=="player"and arg2=="圣盾术"then SendChatMessage("使用圣盾术")F:SetScript("OnEvent",nil)end;end)
/cast 圣盾术

补充一个喊话宏

目标是敌对/友善时不喊话

这个宏也是多用于多个条件语句中

在宏的开头第一行加上

/stopmacro [help]
目标友善时停止宏命令,即不喊话

或者/stopmacro [harm]
目标敌对时停止宏命令。

H. 随机喊话宏

/run local n={"要说的话1","要说的话2","要说的话3"}macroT,macrot=macroT or 0,GetTime()if not UnitCastingInfo("player")and 0==GetSpellCooldown("技能名称")and macrot-macroT>3 then SendChatMessage(n[random(#n)],"SAY")macroT=macrot;end
/cast 技能名称

这个宏做到按一个技能时随机喊话,即红字部分,喊话内容可随意修改。

**补充一个关于/IN 延时宏的*

现在宏里面的 /in 语句已经被BLZ禁用

不过在楼主拥有ace2.0以上的库的情况下
in语句还是可以的...所以——
要么弄一个大脚或者多玩这样的通用插件里面都有ace库的
要么自己去下一个专用库就可以了

I./targetenemy的衍生

/targetenemy
宏本身的作用是切换目标,也就是TAB键的功能

但是这个宏最广泛的使用就是抓贼宏了。。。

当盗贼与敌对方的盗贼互相潜行谁都不可见对方的时候使用
看到对方的盗贼潜行中只是一瞬间 一般来不及手动点选目标施放技能对方盗贼又看不见了,所以抓贼宏应运而生

用法就是在潜行中一边前进一边不停的按,如果发现对方盗贼此宏就能立即向对方盗贼释放闷棍,达到抓贼的目的

#showtooltip 闷棍 
/cleartarget 
/stopattack
/targetenemy
/cast 闷棍 

同理,小德的精灵之火,猎人的猎人印记,战士的嘲讽,都可以做到。

K.随机坐骑宏

很多插件的坐骑助手就是利用了这个宏的原理

/dismount [mounted]
/castrandom [flyable]飞行坐骑1,飞行坐骑2,飞行坐骑3
/castrandom 陆地坐骑1,陆地坐骑2

(这个宏还得自行修改坐骑名称)
这个宏用到了 随机释放命令/castrandom
通过添加条件语句
最后的效果就是
能飞的时候在飞行坐骑123里面随机召唤,不能飞时在陆地坐骑12里面随机召唤

L.打断当前施法立即释放技能宏

这个宏多用在打断技能斩杀技能中。。。

利用到/stopcasting语句达到目的。

例如,打断施法反制
#showtooltip
/stopcasting
/cast 法术反制

同理,反制可以换成斩杀,灭,暗灼这样的斩杀技能,或者其他如拳击,脚踢这一类的的打断技能

M.猎人万能误导宏

#showtooltip 误导
/cast [target=focus, help]误导
/cast [target=focustarget, help]误导
/cast [target=target, help]误导
/cast [target=targettarget, help]误导
/cast [target=pet, nodead, exists]误导

这个宏的作用:
第一行:显示误导技能
第二行:若焦点友善,对焦点使用误导
第三行:若焦点的目标是友善,对焦点的目标使用误导
第四行:若目标友善,对其使用误导
第五行:若目标的目标友善,对其使用误导
第六行:若宠物存在,对宠物使用误导。

总之就是一定能用出误导!


**补充一个小知识*

有公CD的技能和无公CD的技能在宏中的定位

当你想同时释放两个没有公CD的技能时

可以直接在宏内写入
/CAST 技能1
/CAST 技能2

好比盗贼的预谋和偷袭无公CD,这时候如果我们写一个宏
#showtooltip
/CAST 预谋
/CAST 偷袭

这样会同时使用预谋和偷袭,其它职业无公CD的技能也同理。如法师气定羊,猎人逃脱威慑等。

但是如果有公CD的话,就只能依靠/castsequence语句来达到依次释放的效果了
希望大家牢记。

N.巧用stopmacro

/stopmacro [X] 语句,多用在一个宏段落的前面,后面跟一个条件X,指代在X条件下不执行宏命令。
例如
/stopmacro [dead]
/cast 奥术智慧

这个宏的意思就是如果目标死亡,不释放拍智力。

同样的
可以衍生到更多并列的宏命令中

例如
/stopmacro [NOCOMBAT]
/CAST [TARGET=FOCUS,MOD:ALT] 冰枪术
/CAST [TARGET=PLAYER,NOMOD] 奥术智慧

按住ALT时,对焦点BIU,否则对自己拍智力,但是如果不在战斗中,则不执行宏命令

这个就看大家举一反三了

**来个凑数的*

大家喜闻乐见的无敌炉石宏

/castsequence 圣盾术,炉石

**凑数X2*

找怪宏
/TAR XXXXX

xxx改成你要找的怪或者NPC的名字
然后狂按就行了

O./castsequence 语句的另一种用法

相信很多朋友都想做一个“使用A技能,A技能CD用B技能,A技能CD好了用A技能”这样的宏

其实可以利用/castsequence轻松完成

假设A技能的CD时间为X
那么可以做出以下的宏

#showtooltip A
/castsequence reset=x A,B,B,B,B,B,B,B,B,B,B,B,B,B,B,B,B,B

其中B的数量随心情而定

例句

使用深结,深结CD时用biu,深结好了用深结

那么就是
#showtooltip 深度冻结
/castsequence reset=30 深度冻结,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术,冰枪术

这样就能达到你想要的效果啦

是不是很酷炫?

P.一个比较冷门的宏,给目标上标记宏

宏的例句
/script SetRaidTarget("target",X)

X可以换成1-8 中的任意一个

如图
f15420738bd4b31cba8cac6787d6277f9c2ff8f7
宏命令为 /script SetRaidTarget("target",1)
所以效果为给目标上星星

当然
其他的数字分别对应不同的图形

1-星星
2-大饼
3-菱形
4-三角
5-月亮
6-方块
7-红叉
8-骷髅

同样的.
我们可以把这段宏复制到其他的宏命令中,举一反三

例如

#showtooltip
/cast 猎人印记
/script SetRaidTarget("target",8) 

给目标上猎人印记的时候 标记骷髅

效果如图
8bf72b1f95cad1c844a5c7fb7f3e6709c83d510d

Q.取消BUFF宏的最佳用途

前面我们有提到过一个宏,取消buff宏
/cancelaura

效果是取消当前buff
不过我们有一个更棒更酷的用法

如图
667d5fda81cb39dbb5f15d8ad0160924aa183075
宏的语句为
#showtooltip 威慑
/cancelaura 威慑
/cast 威慑

实际作用为
按一下,开启威慑,再按一下,取消威慑!

为什么会达到这个效果呢?
我们从宏的语句来分析机制

第一句 显示威慑
第二句 取消威慑
第三局 释放威慑

我们第一次按的时候
先执行的是取消威慑
但是因为没有威慑效果
所以直接跳过了这个语句
启动第三行的命令,释放威慑

再按一次的时候
由于身上已经有威慑效果了
所以执行第二条语句
取消威慑

酷炫吗?

R.玩宝宝宏.

众所周知
wow中有很多带职业的宝宝
如乌龟,蓝胖,水爸爸,小狗等...

怎么玩宝宝
也是这些职业应该学会的

首先我们来看几个宝宝基本动作宏

宠物攻击命令 /petattack
宠物跟随命令 /petfollow
宠物停留命令 /petstay
宠物协助姿态 /petassist
宠物防御姿态 /petdefensive   
宠物被动姿态 /petpassive   

这些是宝宝的基本动作.
从而我们可以衍生出各种宝宝宏

最简单的
猎人标记宝宝攻击宏

#showtooltip
/cast 猎人印记
/petattack

标记的同时宝宝攻击

与此同时这里要讲到一个招宝宝宏和宝宝技能宏整合的宏

就拿法师的水元素宏为例
#showtooltip
/cast 冰冻术
/stopmacro [target=pet,nodead,exists,nomod]
/cast 召唤水元素

第一行,显示技能
第二行,使用冰环
第三行 如果有宠物,停止命令
第四行 召唤水元素

这个宏的最终作用是有宝宝用冰环 没宝宝招宝宝

其他的DK,术士都可以参考这个宏 稍作修改

10.各职业常用宏!!!

楼主接下来写一点各职业平时能用到的宏,比较偏向大众化,当然也会有点遗漏
如果楼主没有写你想要的,请告诉楼主,楼主一定尽快回复!
好的,话不多说我们马上开始!

A.战士常用宏

换盾盾反宏
#showtooltip 法术反射
/equipslot 16 单手武器名称
/equipslot 17 盾牌名称
/cancelaura 剑刃风暴
/cancelaura 保护之手
/cast 法术反射

致命平静顺劈宏
#showtooltip 顺劈斩
/cast 致命平静
/cast 顺劈斩

切姿态换双手武器宏
#showtooltip 战斗姿态
/cast !战斗姿态
/equipslot 16 双手武器名称

斩杀投掷宏,远处投掷近身斩杀
#showtooltip 斩杀
/cast 斩杀
/cast 投掷

爆发宏
#showtooltip 14
/cancelaura 盾墙
/cast 颅骨战旗
/cast 浴血奋战
/cast 狂暴之怒
/cast 鲁莽
/cast 14

拳击打断宏
#show 拳击
/cancelaura 剑刃风暴
/cancelaura 保护之手
/stopcasting
/cast 拳击

取消保护巨人宏
#showtooltip 巨人打击
/startattack
/cancelaura 剑刃风暴
/cancelaura 保护之手
/cast 10
/cast 巨人打击
(适用于其他技能)

保命宏
#showtooltips 集结呐喊
/stopcasting
/cancelaura 剑刃风暴
/cancelaura 鲁莽
/cast !防御姿态
/equipslot 16 乌克的猢狲片刀
/equipslot 17 密封甲壳
/cast 盾墙
/cast 集结呐喊
/cast 剑在人在
/use 治疗石

冲锋乘胜追击宏 远处冲锋 有乘胜追击打追击(同理,可换成断筋)
#showtooltip 冲锋
/cast 冲锋
/cast 乘胜追击

B.骑士常用宏

爆发宏
#showtooltiP 复仇之怒
/stopcasting
/cast 10
/cast 14
/cast 13
/cast 复仇之怒
/cast 神圣复仇者
/cast 远古列王守卫

惩戒骑一键输出宏(建议在做任务的时候使用,不建议打副本的时候用)
/startattack
/petattack
/castsequence reset=0 0,0,0,0,驱邪术
/castsequence reset=0 0,0,0,十字军打击,0
/castsequence reset=0 0,0,审判,0,0
/castsequence reset=0 0,愤怒之锤,0,0,0
/castsequence reset=0 圣殿骑士的裁决,0,0,0,0

防骑一键拉怪宏单拉版
/castsequence reset=5 正义之锤,审判,奉献,正义之锤,神圣愤怒,审判,十字军打击,奉献,十字军打击,审判,神圣愤怒,十字军打击,圣洁护盾,审判,十字军打击,奉献,神圣 愤怒,十字军打击,审判,十字军打击,奉献,审判,十字军打击,神圣愤怒,圣洁护盾
/cast 正义盾击
/cast 荣耀圣令
/cast 复仇者之盾

防骑一键拉怪宏群拉版
/castsequence reset=5 正义之锤,审判,奉献,正义之锤,神圣愤怒,审判,正义之锤,奉献,正义之锤,审判,神圣愤怒,正义之锤,圣洁护盾,审判,正义之锤,奉献,神圣愤怒,正义之锤,审判,正义之锤,奉献,审判,正义之锤,神圣愤怒,圣洁护盾
/cast 正义盾击
/cast 荣耀圣令
/cast 复仇者之盾

奶骑驱散宏,当目标友方则对其释放清洁术,若目标敌对则对目标的目标清洁术,若无目标则对自己清洁,可改成其他技能,是一样的效果
#showtooltip 清洁术
/stopcasting
/cast [target=mouseover,help][help][target=targettarget,help][]清洁术
/cleartarget [dead,noexists]

C.DK常用宏

开巫妖自己加血宏
#showtooltip 巫妖之躯
/cast 巫妖之躯
/cast [target=player]凋零缠绕

冰DK爆发宏
#showtooltip 冰霜之柱
/cast 冰霜之柱
/cast 13
/cast 14
/cast 10

一键吃宝宝宏
#showtooltip 天灾契约
/cast 亡者复生
/cast 天灾契约

D.萨满

萨满的宏就更少了.
不过楼主还是知道几个

增强萨一键输出宏
/startattack
/castsequence reset=combat 元素释放,烈焰震击,熔岩猛击,风暴打击,大地震击,风暴打击,熔岩猛击,元素释放,大地震击,风暴打击,熔岩猛击,烈焰震击,风暴打击,元素释放,大地 震击,熔岩猛击,风暴打击,大地震击,熔岩猛击,风暴打击,元素释放,烈焰震击,熔岩猛击,风暴打击,大地震击

保命宏
#showtooltip 治疗之潮图腾
/CAST 治疗之潮图腾
/CAST 石壁图腾
/CAST 先祖迅捷
/CAST 治疗之涌

嗜血记时宏
#showtooltip
/cast 嗜血
/RA [嗜血]已开,40秒倒数!饰品技能全开集火!
/in 10 /s [嗜血]还剩30秒……
/in 20 /s [嗜血]还剩20秒……
/in 30 /s [嗜血]还剩10秒……
/in 35 /s [嗜血]最后5秒……
/in 40 /s [嗜血]结束

E.猎人

假死宏,取消一切动作假死
#showtooltip 假死
/STOPATTACK
/STOPCASTING
/STOPCASTING
/CAST 假死

无限视距鹰眼宏,可以在引导鹰眼的时候继续释放鹰眼术
#showtooltip 鹰眼术
/cast !鹰眼术

宠物宏,按住SHIFT复活宠物,按住ALT解散宠物,什么都不按治疗宠物
#showtooltip [modifier:shift] 复活宠物;[modifier:alt] 解散宠物;治疗宠物
/cast [modifier:shift] 复活宠物
/cast [modifier:alt] 解散宠物
/cast [nomodifier] 治疗宠物

你懂得宏(先误导,再按宏)
#showtooltip 假死
/cast 奥术射击
/stopcasting
/stopcasting
/stopattack
/cast 假死
/cancelAura 误导

打断当前读条斩杀(沉默)宏
#showtooltip 杀戮射击
/STOPCASTING
/STOPCASTING
/CAST 杀戮射击

可改成沉默射击

宝宝奶自己宏
#showtooltip [modifier:shift] 牺牲咆哮;灵魂治愈
/CAST [target=player] 灵魂治愈
/CAST [target=player] 牺牲咆哮

兽王爆发宏
#showtooltip 狂野怒火
/CAST 狂野怒火
/CAST 疯乱
/CAST 13
/CAST 急速射击

威慑宏,按一下威慑再按一下取消威慑
#showtooltip 威慑
/cancelaura 威慑
/cast 威慑

F.盗贼

背刺出血宏,正面用出血,背面用背刺
#showtooltip
/castsequence reset=0 16,出血
/cast 背刺

毁伤斩击宏,能打斩击就斩击,否则毁伤
#showtooltip 毁伤
/startattack
/castsequence reset=0 9,毁伤
/castsequence reset=0 斩击,9

抓贼宏
#showtooltip 闷棍
/cleartarget
/stopattack
/targetenemy
/cast 闷棍

潜行宏,潜行中按到潜行不破潜
#showtooltip 潜行
/cast !潜行

闪避吃糖宏
#showtooltip 闪避
/CAST 闪避
/CAST 治疗石

爆发宏
#showtooltip 暗影之刃
/startattack
/cast 仇杀
/cast 暗影之刃
/cast 冲动
/cast 13
/cast 14
/cast 10

G.小德

野德一键拉怪宏单拉版本
#showtooltip 裂伤
/castsequence reset=5 裂伤,nil
/castsequence reset=6 割伤,痛击,割伤,精灵之火
/cast 裂伤

野德一键拉怪宏群拉版本
#showtooltip 痛击
/cast [mod:ctrl]横扫
/castsequence reset=6 横扫,痛击,横扫
/cast 裂伤

保命宏
#showtooltip
/cast 生存本能
/cast 树皮术
/use 治疗石
/cast 自然迅捷
/cast 10
/cast 13
/console autounshift 0
/cast [target=player] 治疗之触
/console autounshift 1

一键变身宏
#showtooltip
/cast [flyable,nocombat,nomod]!迅捷飞行形态;[form:4,nomod,outdoors] [nomod.nocombat,outdoors][noform,outdoors]!旅行形态;[swimming,nomod]!水栖形态; [form:1,nomod]!巨熊形态;[form:3,nomod]!猎豹形态;[form:5,nomod][nomod,indoors]!生命之树
/cancelform [form:6][mod]

H.武僧

武僧作为新职业楼主还没收集到什么好用的宏 就写个爆发宏凑数吧...

爆发宏
#showtooltip
/CAST 虎眼酒
/CAST 豪能酒
/CAST 白虎下凡
/CAST 13
/CAST 14
/CAST 10

I.牧师

牧师作为奶和输出都没有什么需要特别关注的技能...

J.术士

吃糖宏
#showtooltip 治疗石
/CAST 黑暗再生
/CAST 治疗石

爆发宏
#showtooltip
/cast 黑暗灵魂:易爆
/cast 13
/cast 14
/cast 10

其中黑魂不同天赋名字不同,就请自行更换啦

K.法师

打断当前施法反制宏(也适用于其他技能)
#showtooltip
/stopcasting
/Cast 法术反制

冰箱宏 按一下冰箱 再按取消
#showtooltip 寒冰屏障
/stopcasting
/cancelaura 寒冰屏障
/Cast 寒冰屏障

闪现宝宝跟随宏
#showtooltip 闪现术
/stopcasting
/cast 闪现术
/petfollow
/petpassive

水元素冰环宏,没宝宝招宝宝,有宝宝冰环
#showtooltip
/cast 冰冻术
/stopmacro [target=pet,nodead,exists,nomod]
/cast 召唤水元素

补充一个好用的

战场报数宏(之前报废)

/script if not ce or not le or GetTime()-le>10 then ce=0; end; le=GetTime(); ce=ce+1; SendChatMessage( GetMinimapZoneText().."发现"..ce.."名敌人!", "INSTANCE_CHAT")

这个宏比较有意思

当你在守点的时候,突然来了一大票人,又不好打字的时候用

按几次,报几个人,十分人性化

对于楼主这种常年不开麦的人来说太爽啦